% TW -- uppercase letters   


beginchar("A",46ut#,39ut#,0);
pickup va_pen;
z1=(0ut,0ut)+z7;
z2=(12ut,6ut)+z7;
z3=(36ut,39ut)+z7;
z4=(30ut,0ut)+z7;
z5=(12ut,14ut)+z7;
z6=(46ut,18ut)+z7;
z7=(0ut,0ut);
%
draw z1{right}..z2--z3
  & z3--z4;
draw z5{dir 345}..z6{an};
%
labels(range 1 thru 7);
endchar;

beginchar(oct"035",46ut#,47ut#,0);   % A-Umlaut
pickup va_pen;
z1=(0ut,0ut);
z2=(12ut,6ut);
z3=(36ut,39ut);
z4=(30ut,0ut);
z5=(12ut,14ut);
z6=(46ut,18ut);
z7=(32ut,46ut);
z8=(41ut,46ut);
%
draw z1{right}..z2--z3
  & z3--z4;
  draw z5{dir 345}..z6{an};
%
pickup pencircle scaled  4ut;
drawdot z7;drawdot z8;
%
labels(range 1 thru 8);
endchar;


beginchar("B",36ut#,39ut#,0);
pickup va_pen;
z1=(6ut,39ut);
z2=(21ut,39ut);
z3=(27ut,31ut);
z4=(10ut,19ut);
z5=(28ut,9ut);
z6=(0ut,0ut);
z7=(12ut,39ut);
z8=(6ut,0ut);
%
draw z1--z2..z3{down}...z4{left}
  & z4{right}..z5{down}...z8{left}--z6;
  draw z7--z8;
labels(range 1 thru 8);
endchar;

beginchar("C",32ut#,39ut#,0ut#);
pickup va_pen;
z1=(27ut,36ut);
z2=(18ut,39ut);
z3=(0ut,10ut);
z4=(8ut,0ut);
z5=(32ut,18ut);
z6=(14ut,2ut);
%
draw z1..z2{left}..z3{down}..z4{right}..z6--z5;

labels(range 1 thru 6);
endchar;

beginchar("D",42ut#,39ut#,0ut#);
pickup va_pen;
z1=(3ut,39ut);
z2=(17ut,39ut);
z3=(34ut,24ut);
z4=(0ut,0ut);
z5=(11ut,39ut);
z6=(3ut,0ut);
%
draw z1--z2..z3{down}..z6{left}--z4;
draw z5--z6;
labels(range 1 thru 6);
endchar;

beginchar("E",32ut#,39ut#,0ut#);
pickup va_pen;
z1=(24ut,37ut);
z2=(6ut,29ut);
z3=(15ut,19ut);
z4=(0ut,8ut);
z5=(10ut,0ut);
z6=(32ut,18ut);
z7=(15ut,2ut);
%
draw z1..z2{down}..z3
  & z3..z4..z5{right}..z7--z6{an};
labels(range 1 thru 6);
endchar;

beginchar("F",30ut#,39ut#,0ut#);
pickup va_pen;
z1=(8ut,39ut);
z2=(0ut,0ut);
z3=(0ut,39ut);
z4=(26ut,39ut);
z5=(-2ut,18ut);
z6=(23ut,18ut);
%
draw z3--z4;
draw z1--z2;
draw z5{dir 340}..z6{dir 8};
labels(range 1 thru 6);
endchar;

beginchar("G",39ut#,39ut#,19ut#);
pickup va_pen;
z1=(28ut,36ut);
z2=(21ut,39ut);
z3=(0ut,8ut);
z4=(5ut,0ut);
z5=(25ut,19ut);
z6=(22ut,0ut);
z7=(12ut,-19ut);
z8=(8ut,-15ut);
z9=(13ut,-7ut);
z10=(39ut,18ut);
%
draw z1..z2{left}..z3{down}..z4{right}..z5{z5-z6}
  & z5--z6{z6-z5}..z7{left}..z8{up}..z9{z10-z9}---z10;
labels(range 1 thru 10);
endchar;

beginchar("H",35ut#,39ut#,0ut#);
pickup va_pen;
z1=(6ut,39ut);
z2=(0ut,0ut);
z3=(27ut,39ut);
z4=(21ut,0ut);
z5=(-4ut,14ut);
z6=(35ut,18ut);
%
draw z1--z2;
draw z3--z4;
draw z5{dir 340}..z6{dir 30};
labels(range 1 thru 6);
endchar;

beginchar("I",29ut#,39ut#,0ut#);
pickup va_pen;
z1=(9ut,39ut);
z2=(25ut,39ut);
z3=(20ut,10ut);
z4=(10ut,0ut);
z5=(0ut,5ut);
%
draw z1--z2
  & z2--z3..z4{left}..z5;
labels(range 1 thru 5);
endchar;

beginchar("J",21ut#,39ut#,19ut#);
pickup va_pen;
z1=(0ut,39ut);
z2=(15ut,39ut);
z3=(9ut,4ut);
z4=(-2ut,-19ut);
z5=(-7ut,-14ut);
z6=(-4ut,-5ut);
z7=(21ut,18ut);
%
draw z1--z2
 & z2--z3{z3-z2}...z4{left}..z5{up}..z6--z7;
labels(range 1 thru 7);
endchar;

beginchar("K",41ut#,39ut#,0ut#);
pickup va_pen;
z1=(8ut,39ut);
z2=(0ut,0ut);
z3=(31ut,39ut);
z4=(4ut,20ut);
z5=(17ut,2ut);
z6=(21ut,0ut);
z7=(41ut,18ut);
z8=(26ut,3ut);
%
draw z1--z2;
draw z3..z4
 & z4--z5..z6{right}..z8--z7;
labels(range 1 thru 8);
endchar;

beginchar("L",38ut#,39ut#,0ut#);
pickup va_pen;
z1=(14ut,39ut);
z2=(8ut,32ut);
z3=(4ut,8ut);
z4=(0ut,0ut);
z5=(17ut,0ut);
z6=(38ut,18ut);
z7=(22ut,2ut);
%
draw z1..z2..z3..z4
 & z4{dir 40}..z5{right}..z7--z6;
labels(range 1 thru 7);
endchar;

beginchar("M",70ut#,39ut#,0ut#);
pickup va_pen;
z1=(0ut,0ut);
z2=(8ut,4ut);
z3=(33ut,39ut);
z4=(25ut,0ut);
z5=(53ut,39ut);
z6=(47ut,4ut);
z7=(51ut,0ut);
z8=(70ut,18ut);
z9=(55ut,2ut);
%
draw z1{right}..z2--z3
 & z3--z4
 & z4--z5
 &z5--z6{z6-z5}..z7{right}..z9--z8;
labels(range 1 thru 9 );
endchar;

beginchar("N",42ut#,39ut#,0ut#);
pickup va_pen;
z1=(0ut,0ut);
z2=(5ut,5ut);
z3=(11ut,39ut);
z4=(29ut,0ut);
z5=(35ut,30ut);
z6=(40ut,39ut);
%
draw z1{right}..z2{z3-z2}--z3
 & z3--z4
 & z4--z5{z5-z4}...z6;
labels(range 1 thru 6);
endchar;

beginchar("O",36ut#,39ut#,0ut#);
pickup va_pen;
z1=(28ut,25ut);
z2=(10ut,0ut);
z3=(0ut,16ut);
z4=(17ut,39ut);
%
draw z1{down}..z2{left}..z3{up}..z4{right}..cycle;
labels(range 1 thru 4);
endchar;

beginchar(oct"036",36ut#,47ut#,0ut#);   % O-Umlaut
pickup va_pen;
z1=(28ut,25ut);
z2=(10ut,0ut);
z3=(0ut,16ut);
z4=(17ut,39ut);
z5=(14ut,46ut);
z6=(22ut,46ut);
%
draw z1{down}..z2{left}..z3{up}..z4{right}..cycle;
%
pickup pencircle scaled  4ut;
drawdot z5; drawdot z6;
labels(range 1 thru 6);
endchar;


beginchar("P",28ut#,39ut#,0ut#);
pickup va_pen;
z1=(0ut,39ut);
z2=(17ut,39ut);
z3=(26ut,31ut);
z4=(4ut,19ut);
z5=(7ut,39ut);
z6=(0ut,0ut);
%
draw z1--z2..z3{down}...z4{left};
draw z5--z6;
labels(range 1 thru 6);
endchar;

beginchar("Q",44ut#,39ut#,0ut#);
pickup va_pen;
z1=(28ut,25ut);
z2=(10ut,0ut);
z3=(0ut,16ut);
z4=(17ut,39ut);
z5=(13ut,12ut);
z6=(18ut,5ut);
z7=(24ut,0ut);
z8=(30ut,3ut);
z9=(44ut,18ut);
%
draw z1{down}..z2{left}..z3{up}..z4{right}..cycle;
draw z5--z6..z7..z8--z9;
labels(range 1 thru 9);
endchar;

beginchar("R",39ut#,39ut#,0ut#);
pickup va_pen;
z1=(5ut,39ut);
z2=(14ut,39ut);
z3=(21ut,30ut);
z4=(3ut,19ut);
z5=(7ut,39ut);
z6=(0ut,0ut);
z7=(17ut,3ut);
z8=(21ut,0ut);
z9=(25ut,3ut);
z10=(39ut,18ut);
%
draw z1--z2..z3{down}..z4
  & z4--z7{z7-z4}..z8..z9---z10;
draw z5--z6;
labels(range 1 thru 10);
endchar;

beginchar("S",32ut#,39ut#,0ut#);
pickup va_pen;
z1=(0ut,3ut);
z2=(10ut,0ut);
z3=(22ut,9ut);
z4=(8ut,30ut);
z5=(17ut,39ut);
z6=(25ut,36ut);
%
draw z1..z2{right}..z3{up}..z4{up}..z5{right}..z6;
labels(range 1 thru 6);
endchar;

beginchar("T",31ut#,39ut#,0ut#);
pickup va_pen;
z1=(15ut,39ut);
z2=(8ut,0ut);
z3=(0ut,39ut);
z4=(29ut,39ut);
%
draw z1--z2;
draw z3--z4;
labels(range 1 thru 4);
endchar;

beginchar("U",45ut#,39ut#,0ut#);
pickup va_pen;
z1=(6ut,39ut);
z2=(0ut,8ut);
z3=(6ut,0ut);
z4=(25ut,20ut);
z5=(29ut,39ut);
z6=(22ut,5ut);
z7=(25ut,0ut);
z8=(45ut,18ut);
z9=(29ut,2ut);
%
draw z1--z2..z3{right}..z4..z5
  & z5--z6{z6-z5}..z7..{z8-z9}z9--z8;
labels(range 1 thru 9);
endchar;

beginchar(oct"037",45ut#,47ut#,0ut#);   % U-Umlaut
pickup va_pen;
z1=(6ut,39ut);
z2=(0ut,8ut);
z3=(6ut,0ut);
z4=(25ut,20ut);
z5=(29ut,39ut);
z6=(22ut,5ut);
z7=(25ut,0ut);
z8=(45ut,18ut);
z9=(29ut,2ut);
z10=(13ut,46ut);
z11=(22ut,46ut);
%
draw z1--z2..z3{right}..z4..z5
  & z5--z6{z6-z5}..z7..{z8-z9}z9--z8;
%
pickup pencircle scaled  4ut;
drawdot z10; drawdot z11;
%
labels(range 1 thru 9);
endchar;


beginchar("V",41ut#,39ut#,0ut#);
pickup va_pen;
z1=(7ut,39ut);
z2=(0ut,0ut);
z3=(34ut,34ut);
z4=(41ut,39ut);
%
draw z1--z2
 & z2--z3{z4-z3}...z4;
labels(range 1 thru 4);
endchar;

beginchar("W",58ut#,39ut#,0ut#);
pickup va_pen;
z1=(8ut,39ut);
z2=(3ut,0ut);
z3=(30ut,39ut);
z4=(26ut,0ut);
z5=(53ut,35ut);
z6=(58ut,39ut);
%
draw z1--z2
 & z2--z3
 & z3--z4
 & z4--z5{z5-z4}...z6;
labels(range 1 thru 6);
endchar;

beginchar("X",48ut#,39ut#,0ut#);
pickup va_pen;
z1=(8ut,39ut);
z2=(22ut,5ut);
z3=(28ut,0ut);
z4=(33ut,3ut);
z5=(48ut,18ut);
z6=(33ut,39ut);
z7=(0ut,0ut);
%
draw z1--z2..z3..z4{z5-z4}---z5;
draw z6--z7;
labels(range 1 thru 7);
endchar;

beginchar("Y",43ut#,39ut#,19ut#);
pickup va_pen;
z1=(6ut,39ut);
z2=(0ut,5ut);
z3=(9ut,0ut);
z4=(30ut,39ut);
z5=(22ut,-5ut);
z6=(14ut,-19ut);
z7=(10ut,-15ut);
z8=(15ut,-7ut);
z9=(43ut,18ut);
%
draw z1--z2{z2-z1}..z3{right}...z4{z4-z5}
 & z4--z5{z5-z4}..z6{left}..z7..z8{z9-z8}---z9;
labels(range 1 thru 9);
endchar;

beginchar("Z",41ut#,39ut#,0ut#);
pickup va_pen;
z1=(7ut,39ut);
z2=(32ut,39ut);
z3=(0ut,0ut);
z4=(22ut,0ut);
z5=(27ut,3ut);
z6=(41ut,18ut);
%
draw z1--z2
 & z2--z3
 & z3{dir 20}..z4{right}..z5{z6-z5}---z6;
labels(range 1 thru 6);
endchar;